reciproka-ops/outputs.nix

{
  self,
  hakyll-skeleton,
  jfdic-web,
  nix,
  nixops,
  nixpkgs,
  nixpkgsUnstable,
  resrok-web,
  utils,
  voc-web,
  ...
} @ inputs:
(utils.lib.eachDefaultSystem (system: let
  pkgs =
    nixpkgs.legacyPackages."${system}";
in {
  devShell =
    pkgs.callPackage
    ./shell.nix {
      inherit (nix.packages."${pkgs.system}") nix;
      inherit (nixpkgsUnstable.legacyPackages."${pkgs.system}") alejandra;
      nixops = nixops.defaultPackage."${pkgs.system}";
    };
}))
// {
  nixopsConfigurations.default = {
    inherit nixpkgs;
    network = {
      description = "jfdic-ops nodes";
      enableRollback = true;
      storage.legacy = {
        databasefile = "~/.nixops/deployments.nixops";
      };
    };
    defaults = {
      system.autoUpgrade.enable = false; # Disabled as it conflicts with NixOps
      _module.args.inputs = inputs; # make flake inputs accessiable in NixOS
      imports = [./profiles/host_common.nix];
    };
    toscano = import ./hosts/toscano.nix;
  };
}