# Weechat application configuration common to all hosts
{
  config,
  pkgs,
  lib,
  ...
}: {
  environment.systemPackages = with pkgs; [
    aspell # Required for spell checking in weechat
    aspellDicts.en # Required for spell checking in weechat
    aspellDicts.en-computers # Required for spell checking in weechat
    aspellDicts.en-science # Required for spell checking in weechat
    (weechat.override {
      configure = {availablePlugins, ...}:
        with weechatScripts; {
          plugins = with availablePlugins; [
            lua
            perl
            (python.withPackages (ps:
              with ps; [
                dbus-python
                websocket_client # Required by wee-slack
                weechat-matrix # https://github.com/NixOS/nixpkgs/pull/79669#issuecomment-584249420
              ]))
          ];
          scripts = [
            wee-slack # A WeeChat plugin for Slack.com
            weechat-autosort # Automatically or manually keep your buffers sorted
            weechat-matrix # Weechat communication over the Matrix protocol
            weechat-otr # WeeChat script for Off-the-Record messaging
          ];
        };
    })
    weechatScripts.weechat-matrix # Weechat communication over the Matrix protocol
  ];
}